Management Portal: how to view globals in opposite order?

 

Class Test.Global Extends %Global
{

ClassMethod GetFetch(ByRef qHandle As %Binary, ByRef Row As %List, ByRef AtEnd As %Integer = 0) As %Status [ Internal, PlaceAfter = GetExecute ]
{
    Set $zt="ERROR"
    Set idx=$p(qHandle,"^",2)
    Set Index=$p(qHandle,"^")
    Set idx=$Order($$$ISCQUERYTEMP(Index,idx),-1,Row)
    If idx="" {
        Set Namespace=qHandle("Namespace")
        Set SearchMask=qHandle("SearchMask")
        Set LastNode=qHandle("LastNode")
        Set NameFormat=qHandle("NameFormat")
        Set ValueFormat=qHandle("ValueFormat")
        Set OldNsp=$zu(5),%UI="CHUI",Count=100
        If Namespace'=OldNsp ZN Namespace
        Set data=$$page^%Wgdisp(SearchMask,LastNode,.Count,0,"","",1,NameFormat,ValueFormat)
        If $zu(5)'=OldNsp ZN OldNsp
        If 'Count Set AtEnd=1,Row="" Quit $$$OK
        ;
        Kill $$$ISCQUERYTEMP(Index)
        For i=1:1:Count {
            Set rec=$p(data,$$$del1,i),subs=$p(rec,$$$del2),val=$p(rec,$$$del2,2)
            Set nf=$p(rec,$$$del2,3),vf=$p(rec,$$$del2,4)
#;SML618+
#;Setup ^CacheTemp with a subroutine in case it overflows the $LB() list.
            d BuildCacheTemp
#;SML618-
        }
        Set qHandle("LastNode")=..Unquote(subs,1)
        Set qHandle=Index_"^"
        Quit ..GetFetch(.qHandle,.Row,.AtEnd)
    } Else {
#;SML618+
#;If there is extension of data then set them to Row array for %ResultSet to get them.
        if $d($$$ISCQUERYTEMP(Index,idx,1)) {
            Set Row(1)=$$$ISCQUERYTEMP(Index,idx,1)
            if $d($$$ISCQUERYTEMP(Index,idx,2)) {
                Set Row(2)=$$$ISCQUERYTEMP(Index,idx,2)
            }
        }
#;SML618-
        Set qHandle=Index_"^"_idx
    }
    Quit $$$OK
ERROR Set $zt=""
    If $g(OldNsp)'="",$zu(5)'=$g(OldNsp) ZN OldNsp
    Quit $$$ERROR($$$CacheError,$ze)
#;SML618+
#;Set the data extension to two or three pieces if it could not fit in one piece.
BuildCacheTemp s $zt="BuildErr1"
    i subs["(" {
        s sub1="("_$p(subs,"(",2,999)
    } else {
        s sub1=""
    }
    s Perm=$s(qHandle("GetPermissions")=0:"",1:$$GetGlobalPermission^%SYS.SECURITY(Namespace,$p(subs,"(",1),sub1,1))
    Set $$$ISCQUERYTEMP(Index,i)=$lb(subs,val,nf,vf,Perm)
    Q
BuildErr1 s $zt="BuildErr2"
    Set $$$ISCQUERYTEMP(Index,i)=$lb(subs,$e(val,1,$l(val)\2),nf,vf,$g(Perm))
    Set $$$ISCQUERYTEMP(Index,i,1)=$lb("",$e(val,$l(val)\2+1,$l(val)),"","","")
    Q
BuildErr2 s $zt=""
    Set $$$ISCQUERYTEMP(Index,i)=$lb(subs,$e(val,1,$l(val)\3),nf,vf,$g(Perm))
    Set $$$ISCQUERYTEMP(Index,i,1)=$lb("",$e(val,$l(val)\3+1,$l(val)\3*2),"","","")
    Set $$$ISCQUERYTEMP(Index,i,2)=$lb("",$e(val,$l(val)\3*2+1,$l(val)),"","","")
    Q
#;SML618-
}

}

Class Test.GlobalViewPane Extends %CSP.UI.System.GlobalViewPane
{

/// Load global data
Method LoadGlobal(Namespace As %String, Mask As %String, LastSub As %String, NodeCount As %Integer, TotalCount As %Integer, chkEdit As %Boolean) As %Boolean
{
    Set $ZT = "Trap"
    Set AtEnd = 0
    Set msgTruncate = $$$Text("...Warning: string truncated!")
    Do {
        //If $G(Namespace) '= "" Set defaultNS = Namespace
        //Else  Set defaultNS = $G(%request.Data("$NAMESPACE",1))
        Set tRS = ##class(%ResultSet).%New("Test.Global:Get")
        Set tSC = tRS.Execute(Namespace,$G(Mask),"",2,2,chkEdit)
        Set TotalCount = 0
        While (tRS.Next() & (TotalCount < NodeCount)) {
            Set TotalCount = TotalCount + 1
            Set sSubs = tRS.GetData(1)
            Set sData = tRS.GetData(2)
            If sSubs '= "" {
                Set LastSub = sSubs
                If $L(sData) > 8000 Set sData = $E(sData,1,8000)_msgTruncate
                Set espSub = $ZCVT(sSubs,"O","HTML")
                Set espData = $ZCVT(sData,"O","HTML")
                Set tClass = $S(TotalCount#2:"EvenRow",1:"OddRow")
                &html<<tr class="#(tClass)#"><td class="idstyle">#(TotalCount)#:&nbsp;</td>>
                &html<<td id="nid_#(TotalCount)#" style="" nowrap>#(espSub)#</td><td>=</td>>    

                If chkEdit,tRS.Data("Permissions")["WRITE" {
                    &html<<td style="" nowrap><a class="nodelink" href="javascript:selectNode('#(TotalCount)#',1)">#(espData)#</a>>
                } Else {
                    &html<<td style="" nowrap>#(espData)#</td></tr>>
                }

            }
        }
        Set EventDesc = "View Global"
        Set EventData = "View global node: "_Mask_$$$CRLF_"Allow edit: "_chkEdit_$$$CRLF_"Total subscript: "_TotalCount
        $$$SMPAuditView
        If 'tRS.Next() Set AtEnd = 1
    } While (0)    
Done
    Quit AtEnd
Trap
    Set $ZT=""    
    Write "Error loading global ",$ZE,!
    Goto Done
}

}

<AutoPage pagename="View Global Data" parentpage="UtilExpGlobalList.csp" stylesheet="intersystems.css" USENAMESPACE="1">

<Pane name="Title" type="%CSP.Util.SMTitlePane">
    <Text>View Global Data</Text>
</Pane>

<Pane name="Detail" type="Test.GlobalViewPane">
</Pane>

</AutoPage>