How to efficiently store historical data, similar to current data, without mixing physical storage ?

Thanks Eduard for sharing your code implementing a very powerful approach of data snapshot.
 

Thanks Robert for your comment.
 

Merging globals is exactly what the toArchive method does here :

Class data.archive.person Extends (%Persistent, data.current.person)
{
Parameter DEFAULTGLOBAL = "^off.person";
/// Description
ClassMethod archive(purgeArchive As %Integer = 0, purgeSource As %Integer = 0) As %Status
{
set sc = $$$OK , tableName = ""
set (archived,archivedErrors, severity) = 0
set sourceClassName = $PIECE(##class(%Dictionary.ClassDefinition).%OpenId(..%ClassName(1)).Super,",",2)
set targetClassName = ..%ClassName(1)

set sourceClass = ##class(%Dictionary.ClassDefinition).%OpenId(sourceClassName) 
set targetClass = ##class(%Dictionary.ClassDefinition).%OpenId(targetClassName)

set sourceDataLocation = sourceClass.Storages.GetAt(1).DataLocation
set sourceIndexLocation = sourceClass.Storages.GetAt(1).IndexLocation
set sourceStreamLocation = sourceClass.Storages.GetAt(1).StreamLocation

set targetDataLocation = targetClass.Storages.GetAt(1).DataLocation
set targetIndexLocation = targetClass.Storages.GetAt(1).IndexLocation
set targetStreamLocation = targetClass.Storages.GetAt(1).StreamLocation

set tableName = $$$CLASSsqlschemaname($$$gWRK,sourceClassName) _"."_  $$$CLASSsqltablename($$$gWRK,sourceClassName)

if $ISOBJECT(sourceClass) 
 & $ISOBJECT(targetClass)
 & tableName '= "" {
    if $ISOBJECT(sourceClass.Storages.GetAt(1)) 
     & $ISOBJECT(targetClass.Storages.GetAt(1))
     {
        set tStatement=##class(%SQL.Statement).%New(1) 
        kill sql
        set sql($i(sql)) = "SELECT" 
        set sql($i(sql)) = "id"  
        set sql($i(sql)) = "FROM"
        set sql($i(sql)) = tableName
        set sc = tStatement.%Prepare(.sql) 
        set result = tStatement.%Execute()

        kill:purgeArchive @targetDataLocation, @targetIndexLocation, @targetStreamLocation 

        while result.%Next() {
            set source = $CLASSMETHOD(sourceClassName,"%OpenId",result.%Get("id"))

            if $ISOBJECT(source) {
                set archive = $CLASSMETHOD(targetClassName,"%New")

                for i = 1:1:sourceClass.Properties.Count() {
                    set propertyName = sourceClass.Properties.GetAt(i).Name
                    set $PROPERTY(archive,propertyName) = $PROPERTY(source,propertyName)
                }

                set sc = archive.%Save()
                if sc {
                    set archived = archived + 1
                } else {
                    set archivedErrors = archivedErrors + 1
                }
            }
        }

        kill:purgeSource @sourceDataLocation, @sourceIndexLocation, @sourceStreamLocation

        set msg ="archive data from " _ sourceClassName _ " into "_ targetClassName _ " result:" _ archived _ " archived (errors:" _ archivedErrors _ ")"

   } else {
        set severity = 1
        set msg = "ERROR WHILE ARCHIVING " _ sourceClassName _ " in "_ targetClassName _ " : " _ " classes have not storage definition"
    }
} else {
    set severity = 1
    set msg = "ERROR WHILE ARCHIVING " _ sourceClassName _ " in "_ targetClassName _ " : " _ " classes not found in %Dictionary.ClassDefinition"
}
do ##class(%SYS.System).WriteToConsoleLog(msg,0,severity)
Return sc
}
ClassMethod toArchive(purgeArchive As %Integer = 0, purgeSource As %Integer = 0) As %Status
{
set sc=$$$OK
set sourceClassName = $PIECE(##class(%Dictionary.ClassDefinition).%OpenId(..%ClassName(1)).Super,",",2)
set targetClassName = ..%ClassName(1)
set sourceClass = ##class(%Dictionary.ClassDefinition).%OpenId(sourceClassName) 
set targetClass = ##class(%Dictionary.ClassDefinition).%OpenId(targetClassName)

if $ISOBJECT(sourceClass) 
 & $ISOBJECT(targetClass) {
    if $ISOBJECT(sourceClass.Storages.GetAt(1)) 
     & $ISOBJECT(targetClass.Storages.GetAt(1))
     {

        set sourceDataLocation = sourceClass.Storages.GetAt(1).DataLocation
        set sourceIndexLocation = sourceClass.Storages.GetAt(1).IndexLocation
        set sourceStreamLocation = sourceClass.Storages.GetAt(1).StreamLocation

        set targetDataLocation = targetClass.Storages.GetAt(1).DataLocation
        set targetIndexLocation = targetClass.Storages.GetAt(1).IndexLocation
        set targetStreamLocation = targetClass.Storages.GetAt(1).StreamLocation

        kill:purgeArchive @targetDataLocation, @targetIndexLocation, @targetStreamLocation 

        merge @targetDataLocation = @sourceDataLocation
        merge @targetIndexLocation = @sourceIndexLocation
        merge @targetStreamLocation = @sourceStreamLocation

        set ^mergeTrace($i(^mergeTrace)) = $lb($zdt($h,3),sourceDataLocation)

        kill:purgeSource @sourceDataLocation, @sourceIndexLocation, @sourceStreamLocation

        set severity = 0
        set msg = "ARCHIVING " _ sourceClassName _ " in "_ targetClassName _ " SUCCESSFULLY"
                

    } else {
        set severity = 1
        set msg = "ERROR WHILE ARCHIVING " _ sourceClassName _ " in "_ targetClassName _ " : " _ " classes have not storage definition"
    }
} else {
    set severity = 1
    set msg = "ERROR WHILE ARCHIVING " _ sourceClassName _ " in "_ targetClassName _ " : " _ " classes not found in %Dictionary.ClassDefinition"
}
do ##class(%SYS.System).WriteToConsoleLog(msg,0,severity)
return sc
}

Storage Default
{
%%CLASSNAMEnamedobactivcreated^off.personDpersonDefaultData^off.personD^off.personI^off.personS%Storage.Persistent
}
}